[Résolu][Basic] Dossier par défaut de chargement FilePickerLastDirectory

[jeanmi2403]

Bonsoir,
La question me vient d'un de mes correspondants qui travaille sur des documents comportant beaucoup d'images situées dans le même dossier de chaque document.
Il souhaite qu'au chargement de chaque document le dossier par défaut de chargement (Insertion/Image) soit le dossier du document.
J'arrive (par macro) à modifier le chemin des images (Outils/Options/LibreOffice/Chemins/Images)

Code : Tout sélectionner

oPaths = CreateUnoService("com.sun.star.util.PathSettings")
oPaths.Graphic_user = "file:///I:/Projets/Images"

Mais ça n'est pas pris en compte. En fait Writer conserve le dernier chemin utilisé.
J'ai fini par trouver le paramètre dans la configuration avancée.
Arborescence :
Nom de préférence : org.openoffice.Office.Common->Misc>FilePickerLastDirectory->WriterInsertImage
On trouve à cet endroit une clé : org.openoffice.Office.Common:LastDirectory['WriterInsertImage'] Propriété : LastPath puis l'url du dossier.

C'est donc une propriété du FilePicker, mais je ne suis pas très à l'aise avec ce concept que j'utilise pourtant avec d'autres service UNO.
LA question : peut-on accéder à cette propriété et peut-on la modifier ?
Cordialement,
PS : Il se peut que je pose la même question sur le forum anglophone.

[Bidouille]

Titre modifié pour plus de clarté : [API]Accès à la configuration avancée de LibreOffice

Merci de ne pas inventer votre propre balisage à l'avenir.

[jeanmi2403]

Bonjour,

Titre modifié pour plus de clarté :

Si je suis d'accord pour l'invention du balisage API (je cherchais quelque chose de plus général), je ne suis pas d'accord pour la clarté.
Si la solution est trouvée pour le paramètre que je cherche, elle pourra servir d'exemple pour tous les paramètres de la configuration avancée.
Bonne journée,

[jeanmi2403]

Bonsoir,
Avec l'aide de nos amis du forum anglophone, j'ai pu comprendre comment atteindre les paramètres de la configuration avancée. Ce qui m'a donné le code suivant :

Code : Tout sélectionner

Sub InitialiseFilePicker
Dim oDocument as Object
Dim sURL as String
sNodePath = "org.openoffice.Office.Common/Misc/FilePickerLastDirectory"
oDocument = ThisComponent
sURL = Repertoire(oDocument.URL)

Dim args(1) As new com.sun.star.beans.PropertyValue 
args(0).Name = "nodepath" 
args(0).Value = sNodePath
args(1).Name = "EnableAsync" 
args(1).Value = false 

aConfProv = createUnoService("com.sun.star.configuration.ConfigurationProvider") 
aParams = aConfProv.createInstanceWithArguments("com.sun.star.configuration.ConfigurationUpdateAccess", args()) 

aParams.getByname("WriterInsertImage").LastPath = sURL
aParams.commitChanges()
Msgbox (ConvertFromURL(sUrl),MB_ICONINFORMATION,"Répertoire insertion")
end sub

Function Repertoire(sURL As String) As String
Dim sChemin() As String, sRep As String 
	sChemin = Split(sURL,"/")
	sChemin(Ubound(sChemin())) = ""
	Repertoire = join(sChemin, "/")
End Function

Connecté sur l'événement "Ouvrir le document", quelles que soient les actions précédentes, lors de l'ouverture du fichier, le dossier de chargement des images sera celui du document.
Cela fonctionne avec la boîte de dialogue LibreOffice et la boîte système.

Yalb-CheminImages.odt

La méthode (avec quelques adaptions) peut s'appliquer à la plupart des paramètres avancés. Ces paramètres se créent au fur et à mesure des usages.

ParamètresFilePickerLast.PNG

Bonne soirée,