[Résolu] Evénement sur modification du contenu d'une cellule

[cris59]

Je cherche à intercepter le changement de contenu d'une cellule qui contient une liste de validité...

J'ai pensé à PropertiesChangeListener, mais je n'arrive pas à paramétrer correctement...

cris59

[Dude]

Par contenu d'une cellule, tu parles de Calc ?

[cris59]

Oui, de Calc... j'ai oublié de préciser !

cris59

[Dude]

Une interception de touche peut être :

Code : Tout sélectionner

Sub RegisterKeyHandler
     Doc = ThisComponent.getCurrentController
     oKeyHandler = createUnoListener("MyApp_", "com.sun.star.awt.XKeyHandler")
     Doc.addKeyHandler(oKeyHandler) 
End Sub

Sub UnregisterKeyHandler
     Doc.removeKeyHandler(oKeyHandler)
End Sub

Function MyApp_KeyPressed(oEvt) As Boolean
   Doc = ThisComponent.getCurrentController            
   Cell = Doc.getselection()   
   MsgBox ("Code touche : " + oEvt.Keycode)     
End Function  

[bm92]

Dans le panneau de validité, onglet Message d'erreur:
Contenu : Action = macro, puis Parcourir

[cris59]

Non Dude, une interception de touche ne convient pas

Non bm92, ce serait pour récupérer la valeur sélectionnée dans la liste (cela ne génère pas d'erreur)... et donc quand cette valeur change de lancer une macro de récupération

cris59

[Dude]

Code : Tout sélectionner

Sub LanceEcoute
	dim document as object
	oDoc = StarDesktop.CurrentComponent
	oSheets = oDoc.getSheets()
	oSheet = oSheets.getByName("Feuille1")
	oCell = oSheet.getCellRangeByName("A1")
	oListener = CreateUnoListener( "LS_", "com.sun.star.chart.XChartDataChangeEventListener" )
	oCell.addChartDataChangeEventListener(oListener)
	MsgBox "Module d'écoute OK !"
End Sub

Sub LS_ChartDataChanged
	oDoc = StarDesktop.CurrentComponent
	oSheets = oDoc.getSheets()
	oSheet = oSheets.getByName("Feuille1")
	oCell = oSheet.getCellRangeByName("A1")
	
	MsgBox "A1 a changé"
End Sub 

[cris59]

Merci Dude, cela fonctionne ...

mais c'est relativement lent (1 grosse seconde entre le clic de sélection et l'affichage du message), c'est normal?

XPropertiesChangeListener ne pouvait pas être utilisé ?

cris59

[Dude]

mais c'est relativement lent (1 grosse seconde entre le clic de sélection et l'affichage du message), c'est normal?

Ca me le fait aussi chez moi. On dirait que l'info a dû mal à remonter au listener.
Pas d'autre idée pour le moment, désolé.

[cris59]

Merci beaucoup

cris59

[bm92]

Trouvé

Code : Tout sélectionner

Option Explicit

Global oListener as object, oCell as object

Sub LanceEcoute 
dim oDoc as object, oSheets as object, oSheet as object 
oDoc = thisComponent 
oSheets = oDoc.getSheets() 
oSheet = oSheets.getByName("Feuille1") 
oCell = oSheet.getCellRangeByName("C5")
oListener = CreateUnoListener( "LS_", "com.sun.star.util.XModifyListener" ) 
oCell.addModifyListener(oListener)
MsgBox "Module d'écoute ouvert !" 
End Sub


Sub FermeEcoute
oCell.removeModifyListener(oListener)
MsgBox "Module d'écoute fermé !" 
End Sub

Sub LS_modified(evt as object)
dim oCell as object
oCell = evt.Source
print oCell.Value, oCell.String
End Sub


Sub LS_disposing(evt as object)
' routine lancée à la fermeture du document
End Sub

Il faut déclarer en Global non seulement l'objet Listener mais aussi l'objet cellule, afin de les récupérer pour fermer le listener.

[cris59]

Effectivement c'est beaucoup plus rapide... la gestion des événements, ce n'est pas évident !

Merci bm92

cris59