Cerca i corrispettivi

[sanraff]

Buongiorno a tutti, nel file di cui allego esempio, ho realizzato due tabelle, dove in quella di sinistra riporto il resoconto di ogni singolo giorno, a destra invece dovrei riportare in base alla scelta della destinazione, tutte le persone che sono state in quel luogo, con i rispettivi totali.
Quindi attraverso il menù a tendina di scelta, in automatico mi deve restituire il consuntivo.
Spero di esser stato chiaro e nel caso avessi impostato male il progetto, accetto qualsiasi tipo di suggerimento.
Un grazie in anticipo a chi mi darà una mano.

[gioh66]

Salve, effettivamente mi sfugge il senso di cosa vuoi ottenere. Allega un file con qualche dato in più e con il risultato che vuoi ottenere scritto a mano.

[sanraff]

Si, scusami hai ragione, nel primo post avevo invertito l'ordine della richiesta, di seguito la riporto correttamente.

Quindi nel file di cui riallego esempio, ho realizzato due tabelle, dove in quella di destra riporto manualmente il resoconto di ogni singolo giorno, a sinistra invece in modo automatico, dovrei riscontrare in base alla scelta della "Destinazione" che avviene tramite i menù a tendina, tutte le persone che sono state in quel luogo, con i rispettivi campi ad essi associati.
In questo file di esempio, ho riportato uno schema per come dovrebbe avvenire la cosa.
Spero di esser stato chiaro e nel caso avessi impostato male il progetto, accetto qualsiasi tipo di suggerimento, tranne per le tabelle Pivot, perchè non mi piace la loro applicazione, meglio formule matriciali oppure macro.
grazie per la tua collaborazione.

[gioh66]

Ho dato un'occhiata al nuovo file e mi sfugge l'utilità di avere quei tre menù a tendina. Se vuoi solo una tabella di riepilogo per andare ad analizzare i dati di una località te ne basta uno. Se invece vuoi una tabella riassuntiva di ogni località, io farei un foglio per ciascuna località o se le figure coinvolte non sono tantissime anche una tabella per località.
Detto ciò sulla base di ciò che hai postato, la formula da inserire in F3 (per la destinazione polo nord) potrebbe essere

Codice: Seleziona tutto

=SE(VAL.ERRORE(INDICE($O$3:$O$8;PICCOLO(SE(($Q$3:$Q$8=$B$4)+($W$3:$W$8=$B$4)+($AC$3:$AC$8=$B$4)+($AI$3:$AI$7=$B$4);RIF.RIGA($N$3:$N$8)-2);RIF.RIGA($A1))));"";INDICE($O$3:$O$8;PICCOLO(SE(($Q$3:$Q$8=$B$4)+($W$3:$W$8=$B$4)+($AC$3:$AC$8=$B$4)+($AI$3:$AI$7=$B$4);RIF.RIGA($N$3:$N$8)-2);RIF.RIGA($A1))))

e in H3

Codice: Seleziona tutto

=SE(VAL.ERRORE(INDICE($N$3:$N$8;PICCOLO(SE(($Q$3:$Q$8=$B$4)+($W$3:$W$8=$B$4)+($AC$3:$AC$8=$B$4)+($AI$3:$AI$7=$B$4);RIF.RIGA($N$3:$N$8)-2);RIF.RIGA($A1))));"";INDICE($N$3:$N$8;PICCOLO(SE(($Q$3:$Q$8=$B$4)+($W$3:$W$8=$B$4)+($AC$3:$AC$8=$B$4)+($AI$3:$AI$7=$B$4);RIF.RIGA($N$3:$N$8)-2);RIF.RIGA($A1))))

formule matriciali da confermare con ctrl+maiuscolo+invio, e da copiare in basso fin dove serve.
In I3 invece metti

Codice: Seleziona tutto

=SE(VAL.ERRORE(MATR.SOMMA.PRODOTTO($N$3:$N$10=$H19;$O$3:$O$10=$F19;AO$3:AO$10));"";MATR.SOMMA.PRODOTTO($N$3:$N$10=$H19;$O$3:$O$10=$F19;AO$3:AO$10))

e trascini a destra e in basso.
Ti allego il file con le formule fatte nell'area in giallo per verificarle con i risultati che hai inserito.

Ps.: dimenticavo, cerca di non unire le celle se queste sono coinvolte in formule o macro, perchè non vanno d'accordo con questi strumenti.

[sanraff]

Ciao, innanzitutto grazie per lo splendido lavoro e per il consiglio che mi hai dato per come gestire l'unione tra le celle, invece per ciò che riguarda la tabella ed i tre menù a tendina, il progetto lo devo realizzare proprio in quel modo perchè mi occorre fare un'immediata comparazione di valutazione tra i vari luoghi.
Cioè dopo aver inserito il primo luogo ed avuto i campi corrispettivi, a seguire dal secondo menù a tendina inserisco un secondo luogo e così via.
In realtà i menù a tendina devono essere in totale sette e richiamando tutti e sette i luoghi, devo visualizzarli un'unica tabella, come viene illustrato nel secondo file che per ragioni di praticità io mi ero fermato a tre perchè pensavo che una volta ricevuta la soluzioni, per gli altri quattro ci avrei pensato io.
Ad ogni modo è fattibile risolvere la cosa?.
Ancora grazie per il tuo contributo.

[gioh66]

Utilizzando i menù a tendina non saprei come fare. ti propongo un'alternativa.
In colonna A metti le destinazioni e nella B, il numero di volte che compaiono nella tabella "2", utilizzando la formula

Codice: Seleziona tutto

=CONTA.SE($O$3:$AH$12;A3)

poi nel campo destinazione, con la formula

Codice: Seleziona tutto

=SE(RIGHE($A$1:A1)<=$B$3;$A$3;SE(E(RIGHE($A$1:A1)>$B$3;RIGHE($A$1:A1)<=SOMMA($B$3:$B$4));$A$4;SE(E(RIGHE($A$1:A1)>SOMMA($B$3:$B$4);RIGHE($A$1:A1)<=SOMMA($B$3:$B$5));$A$5;SE(E(RIGHE($A$1:A1)>SOMMA($B$3:$B$5);RIGHE($A$1:A1)<=SOMMA($B$3:$B$6));$A$6;SE(E(RIGHE($A$1:A1)>SOMMA($B$3:$B$6);RIGHE($A$1:A1)<=SOMMA($B$3:$B$7));$A$7;SE(E(RIGHE($A$1:A1)>SOMMA($B$3:$B$7);RIGHE($A$1:A1)<=SOMMA($B$3:$B$8));$A$8;SE(E(RIGHE($A$1:A1)>SOMMA($B$3:$B$8);RIGHE($A$1:A1)<=SOMMA($B$3:$B$9));$A$9;"")))))))

vengono ripetute automaticamente, le destinazioni per il numero di volte presente in colonna B.
Per le date la formula diventa

Codice: Seleziona tutto

=SE(VAL.ERRORE(SE($D3="";"";INDICE($M$3:$M$8;PICCOLO(SE(($O$3:$O$8=$D3)+($U$3:$U$8=$D3)+($AA$3:$AA$8=$D3)+($AG$3:$AG$7=$D3);RIF.RIGA($L$3:$L$8)-2);CONTA.SE($D$3:$D3;$D3)))));"";SE($D3="";"";INDICE($M$3:$M$8;PICCOLO(SE(($O$3:$O$8=$D3)+($U$3:$U$8=$D3)+($AA$3:$AA$8=$D3)+($AG$3:$AG$7=$D3);RIF.RIGA($L$3:$L$8)-2);CONTA.SE($D$3:$D3;$D3))))

)
matriciale, da confermare con ctrl+maiuscolo+invio e da copiare in basso
per il nome

Codice: Seleziona tutto

=SE(VAL.ERRORE(SE($D3="";"";INDICE($L$3:$L$8;PICCOLO(SE(($O$3:$O$8=$D3)+($U$3:$U$8=$D3)+($AA$3:$AA$8=$D3)+($AG$3:$AG$7=$D3);RIF.RIGA($L$3:$L$8)-2);CONTA.SE($D$3:$D3;$D3)))));"";SE($D3="";"";INDICE($L$3:$L$8;PICCOLO(SE(($O$3:$O$8=$D3)+($U$3:$U$8=$D3)+($AA$3:$AA$8=$D3)+($AG$3:$AG$7=$D3);RIF.RIGA($L$3:$L$8)-2);CONTA.SE($D$3:$D3;$D3)))))

matriciale, da confermare con ctrl+maiuscolo+invio e da copiare in basso
e per i totali delle quantità per località

Codice: Seleziona tutto

=MATR.SOMMA.PRODOTTO($O$3:$O$10=$D3;Q$3:Q$10;$M$3:$M$10=$E3;$L$3:$L$10=$F3)+MATR.SOMMA.PRODOTTO($AG$3:$AG$10=$D3;AI$3:AI$10;$M$3:$M$10=$E3;$L$3:$L$10=$F3)+MATR.SOMMA.PRODOTTO($AA$3:$AA$10=$D3;AC$3:AC$10;$M$3:$M$10=$E3;$L$3:$L$10=$F3)+MATR.SOMMA.PRODOTTO($U$3:$U$10=$D3;W$3:W$10;$M$3:$M$10=$E3;$L$3:$L$10=$F3)

da trascinare a destra e in basso
Volendo le colonne A e B le puoi nascondere.

[sanraff]

Ciao nell'ultimo file da te allegato, ho provato a fare test e mi sono accorto che se nella tabella dove inserisco i dati, riporto sulla stessa riga, la stessa destinazione ( che potrebbe accadere ), la tabella riepilogativa dove ci sono i campi in giallo mi restituisce dei parametri non corretti ( nomi doppi che non riportano informazioni ).
Allego file per capire se è possibile intervenire ulteriormente, grazie

[gioh66]

Ho controllato il file e mi sono accorto che c'era un errore nei riferimenti della terza formula, inoltre la dove una figura è presente due o più volte nello stesso luogo e nella stessa data, somma i valori di Tot q.tà, ma lascia delle righe vuote.
Per ovviare a questo inconveniente ho creato una tabella d'appoggio da A3 a G3 per sommare la presenza della località, contando però solo una presenza per riga, anche se sono di più. Per farlo ho usato queste formule, da trascinare in basso al bisogno
A3 =SE(CONTA.SE($W3:$AO3;$H$3)>=1;1;0)
B3 =SE(CONTA.SE($W3:$AO3;$H$4)>=1;1;0)
C3 =SE(CONTA.SE($W3:$AO3;$H$5)>=1;1;0)
D3 =SE(CONTA.SE($W3:$AO3;$H$6)>=1;1;0)
E3 =SE(CONTA.SE($W3:$AO3;$H$7)>=1;1;0)
F3 =SE(CONTA.SE($W3:$AO3;$H$8)>=1;1;0)
G3 =SE(CONTA.SE($W3:$AO3;$H$9)>=1;1;0)
Dopo di che ho sostituito la formula in I3 con
I3 =SOMMA(A3:A1000)
I4 =SOMMA(B3:B1000)
I5 =SOMMA(C3:C1000)
I6=SOMMA(D3:D1000)
I7=SOMMA(E3:E1000)
I8=SOMMA(F3:F1000)
I9 =SOMMA(G3:G1000)
Ho messo il range fino alla cella 1000, se serve di più aumenta.
Il resto l'ho lasciato invariato, ho solo aggiunto un SE per non lasciare degli 0 dove non ci sono risultati.

Ps.: alla tabella ho aggiunto una colonna (N) che conta quante volte nella stessa data è stato presente il soggetto. Le colonne da A a J si possono nascondere.