[Risolto] CERCA.VERT su più tabelle

[Oni1985]

Ciao, domanda a scopo informativo, è possibile impostare un cera.vert di un dato su più tabelle contemporaneamente?

In pratica ho necessità di dividere i dati su più tabelle per una semplice questione di spazio, lo so è assurdo ma nonostante ci siano oltre 60.000 celle non mi bastano.

Grazie, ciao

[unlucky83]

se le tabelle sono ordinate, usando le funzioni:
SE
Val.Errore
Cerca.vert
annidandole in maniera corretta, dovresti riuscirci

[Oni1985]

Perfetto, le tabelle che sto costruendo sono tutte ordinate e i riferimenti sono sempre gli stessi, appena le ho pronte sottopongo la formula da annidare, grazie!

[unlucky83]

L'importante è che non spezzi la tabella in un numero eccessivo di tabelle, perchè c'è un limite nell'annidare le funzioni, senza contare che la formula diventa di difficile lettura quindi è facile da sbagliare.

[Oni1985]

Ok infatti voglio capire se è possibile prima di fare il lavoro, le tabelle in tutto dovrebbero essere 6, se non sbaglio si possono annidare fino ad 8 funzioni, la cosa che mi preoccupa è che in ogni tabella ci sono migliaia di dati

[Oni1985]

Allora l'idea teoricamente è qsta: estendere la seguente formula su 6 tabelle che possiedono gli stessi riferimenti

=SE(I10<>""; SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Tessile'!$E$5:$H$65536; 4; 0));"";CERCA.VERT(A10; 'Venduto - Tessile'!$E$5:$H$65536; 4; 0)*1);"")

"Venduto - Tessile" è il primo dei 6 fogli, il punto in cui moltiplico il risultato x 1 (*1) mi serve a recuperare il formato numero perchè per qualche motivo se lo perde nel trasportare i valori nelle tabelle.

Grazie

[unlucky83]

La formula annidata te la presento con gli invii per una facile lettura per la modifica, ti consiglio di copiarla ed incollarla su un editor,modifichi i testi in grassetto, poi ti sbarazzi degli invii e infine copi la formula che ottieni e la inserisci nella cella, sperando che non si è superato il limite. Se si è superato il limite, ti consiglio di passare ad una versione più recente di openoffice, che mette a disposizione molte più righe in un foglio rispetto alla versione 3.1 che hai te.

=SE(I10<>"";
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Tessile'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Foglio2'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Foglio3'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Foglio4'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Foglio5'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Foglio6'!$E$5:$H$65536; 4; 0));
""
;CERCA.VERT(A10; 'Venduto - Foglio6'!$E$5:$H$65536; 4; 0)*1)
;CERCA.VERT(A10; 'Venduto - Foglio5'!$E$5:$H$65536; 4; 0)*1)
;CERCA.VERT(A10; 'Venduto - Foglio4'!$E$5:$H$65536; 4; 0)*1)
;CERCA.VERT(A10; 'Venduto - Foglio3'!$E$5:$H$65536; 4; 0)*1)
;CERCA.VERT(A10; 'Venduto - Foglio2'!$E$5:$H$65536; 4; 0)*1)
;CERCA.VERT(A10; 'Venduto - Tessile'!$E$5:$H$65536; 4; 0)*1)
;"")

[Oni1985]

Ciao ti ringrazio per l'aiuto non ci sarei mai arrivato da solo, ho riscritto la formula come segue (eliminando tutti gli invii):

=SE(I10<>"";
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Tessile'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Grocery'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Casa e comunicazione'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Bazar'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Prod. freschi confez.'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto - Nuovi mercati'!$E$5:$H$65536; 4; 0));
"";
CERCA.VERT(A10; 'Venduto - Nuovi mercati'!$E$5:$H$65536; 4; 0)*1);
CERCA.VERT(A10; 'Venduto - Prod. freschi confez.'!$E$5:$H$65536; 4; 0)*1);
CERCA.VERT(A10; 'Venduto - Bazar'!$E$5:$H$65536; 4; 0)*1);
CERCA.VERT(A10; 'Venduto - Casa e comunicazione'!$E$5:$H$65536; 4; 0)*1);
CERCA.VERT(A10; 'Venduto - Grocery'!$E$5:$H$65536; 4; 0)*1);
CERCA.VERT(A10; 'Venduto - Tessile'!$E$5:$H$65536; 4; 0)*1);
"")

Tuttavia mi dice che la formula contiene un errore, noto che in corrispondenza del CERCA.VERT NUOVI MERCATI tutte le celle A10 diventano di colore nero, questo mi fa supporre che sia stato raggiunto il limite di argomenti...Mi sono accorto che nonostante i dati siano migliaia sono riuscito a farceli stare in un unico foglio affiancando le tabelle, mi scuso se ti ho fatto elaborare questa formula complicatissima, potresti invece aiutarmi ad elaborare la stessa formula applicata su un un solo foglio con riferimenti diversi sulle varie tabelle? Mi spiego, sempre tenendo in considerazione il SE(VAL.ERRORE) devo effettuare un CERCA.VERT su questi riferimenti:

- 'Foglio 1!' $E$5:$H$65536
- 'Foglio 1!' $N$5:$Q$65536
- 'Foglio 1!' $W$5:$Z$65536
- 'Foglio 1!' $AF$5:$AI$65536
- 'Foglio 1!' $AO5:$AR$65536
- 'Foglio 1!' $AX$5:$BA$65536

Grazie mille! Spero si possa fare se no sono rovinato

[Oni1985]

P.s. mi serve per lavoro e uso Excel 2003, siccome mi viene messo a disposizione dell'azienda non posso cambiare software!

[Oni1985]

Credo di aver risolto modificando la tua formula!

=SE(I10<>"";
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto'!$E$5:$H$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto'!$N$5:$Q$65536; 4; 0));
SE(VAL.ERRORE(CERCA.VERT(A10; 'Venduto'!$W$5:$Z$65536; 4; 0));
"";
CERCA.VERT(A10; 'Venduto'!$W$5:$Z$65536; 4; 0)*1);
CERCA.VERT(A10; 'Venduto'!$N$5:$Q$65536; 4; 0)*1);
CERCA.VERT(A10; 'Venduto'!$E$5:$H$65536; 4; 0)*1);
"")

[unlucky83]

Risolto?

[Oni1985]

Sì ho risolto grazie mille per l'aiuto! Domani vedo se ho tempo di aprire una nuova discussione perchè un problema assurdo con un Indice-confronta che per qualche motivo non riesco a far funzionare su tutte le celle, vedo se riesco ad allegare un file perchè è difficile da spiegare senza un esempio